VBA（Visual Basic for Application）における数値の丸めについてまとめておきます。
偶数丸め（JIS丸め、銀行丸め）
VBA標準のRound関数は偶数丸め（JIS丸め、銀行丸め）なのでそのまま使えるのですが、整数部での丸め（小数部桁数に負の値を指定する）ができません。以下の関数を作り、拡張します。
' 偶数丸め（整数部丸め対応）
Public Function RoundHalfEven(ByVal number As Double, Optional ByVal digitsAfterDecimal As Long = 0) As Double
If digitsAfterDecimal < 0 Then
Dim shift As Double
shift = 10 ^ digitsAfterDecimal
RoundHalfEven = Round(number * shift) / shift
Else
RoundHalfEven = Round(number, digitsAfterDecimal)
End If
End Function
四捨五入
Excel VBAの場合、ワークシート関数のRoundを使えばよいのですが、Access や VBScript では使えないので自作しておきます。
' 四捨五入
Public Function RoundHalfUp(ByVal number As Double, Optional ByVal digitsAfterDecimal As Long = 0) As Double
Dim shift As Long
shift = 10 ^ digitsAfterDecimal
'浮動小数点誤差を避けるため十進型に変換する
RoundHalfUp = Fix(CDec(number) * shift + 0.5 * sgn(number)) / shift
End Function
Decimal型はVBAでは宣言できないため、CDec関数で変換する必要があります。Currency 型は小数部4桁に制限されるため使用しません。
なお、Decimal型との演算はDecimal型に変換されて行われます。
? 1.2-1.1
9.99999999999999E-02
? CDec(0)+1.2-1.1
0.1
有効数字に丸め
有効数字に丸める場合です。以下は偶数丸めの場合で上述のRoundHalfEven関数を使用しています。四捨五入で丸める場合は、上述のRoundHalfUp関数に置き換えてください。
桁数の初期値は3桁にしてあります。
'有効数字に丸め（初期値3桁）
Public Function RoundSignificantFigures(ByVal number As Double, Optional ByVal digits As Long = 3) As Double
If number = 0 Then
RoundSignificantFigures = 0
Else
' 偶数丸め
RoundSignificantFigures = RoundHalfEven(number, digits - 1 - Int(Log(number) / Log(10)))
End If
End Function
有効数字取得の考え方は、Oracleで有効数字を取得する。を参考にしてください。
床関数（Floor）
VBAのInt関数は床関数（Floor Function）と同じですので、そのまま使えます。床関数は実数x に対して x 以下の最大の整数と定義されます（Wikipedia
）が、Excelワークシート関数と同様に第2引数に基準値がとれるように拡張します。
' 床関数
Public Function Floor(ByVal number As Double, Optional ByVal significance As Double = 1) As Double
If significance = 0 Or (number > 0 And significance < 0) Then
Err.Raise 5 'プロシージャの呼び出し、または引数が不正です。
End If
Floor = Int(CDec(number) / significance) * significance
End Function
第1引数が正で第2引数が負の場合、正しい結果を返さないので、Excelのワークシート関数 Floorと態度を合わせてエラーにしています。
天井関数（Ceiling, Ceil）
天井関数（Ceiling, Ceil）は、数直線をイメージすると床関数を左右反転したものです。したがって、数値を正負反転して床関数で処理し、元に戻せばよいことになります。
' 天井関数
Public Function Ceiling(ByVal number As Double, Optional ByVal significance As Double = 1) As Double
If significance = 0 Or (number > 0 And significance < 0) Then
Err.Raise 5 'プロシージャの呼び出し、または引数が不正です。
End If
Ceiling = -Int(-CDec(number) / significance) * significance
End Function
